ArduinoでMIDIアナログシーケンサー

しばらく使っていたMIDIキーボードMK-225Cがある日ぶっ壊れてしまったので、バラしてみました。が、原因はよくわからず直すのはあきらめ、改めて見るともともとMIDIコントローラーなのでいろいろ使えそうな部品がありましたので、せっかくですからArduinoに繋げてなにか作ってみることにしました。
部品屋に行ってみたら、以前のペンケースに丁度いい大きさのブレッドボードがあったのでこれをセットしてみたら、形から入るタイプとしては俄然やる気が出た・・・っていうのもあります。

途中の写真を取っていなかったので、とりあえずの完成形はこんな感じ。

ブレッドボード右端の白いチップ（TL552 フォトカプラ）を中心とした部分はMIDI INの回路で、今回は使っていません。
この部分の回路の組み合わせは変わらないので小さい基板にでも組んでしまうのがいいでしょうね。後で作ってみます。
上のVRが8個乗った基板がMK-225から取り外したもので、都合の良いことに裏に4051チップがくっついています。基板の大きさが微妙に大きいので残念ながら筆箱には収まらず。

ハード解説

動作を簡単に解説しますと、8個のVRの値（0〜5Vの電圧）を1個ずつ順番にArduinoのアナログ入力で読み取って、それをMIDI ノートナンバーに変換してMIDI OUTから出力する。基本的にはこれだけです。 ただ、Arduino デュエ…なんとかにはアナログ入力が6個しかありません。ここで活躍するのがアナログマルチプレクサというICです。英語ではMuxと表記されている場合もあります。昔からある汎用ロジックICです。
バラしたVR基板上にちょうど8chマルチプレクサの4051が乗っていましたのでこれをそのまま使います。

4051は8個の接点があるロータリースイッチを手で切り替える感じで、デジタル信号でスイッチを切り替えることのできるICです。（こちらのサイトの解説がわかりやすいです） Arduinoのplaygroundにも4051を使ったキーボードスイッチの資料がありますので参考にしてみてください。
これを使うことで、アナログ入力は1個ですみます。デジタル出力は8chですので3bit=3本分使います。

また、今回は使用していませんが、INH端子を0/1に切り替えることで、このIC自体のON/OFFを切り替えることができます。これによって4051を複数使うことで16ch,24chと増やしていくこともできます。

たいした回路では無いですが、Fritzingと言うソフトの練習を兼ねて回路図を作ってみました。

うーん、おもしろいソフトだと思うんですが、ウチの環境だとこれぐらいの規模でだんだん重くなってきて最後の方はちょっと動作が辛かったです。イラストレーターでシンボルを作って書いた方が早かったかもしれません。

8個のVRと4051以外の部分は、スタートストップ用の押ボタンスイッチ、テンポ調整用のVR、インジケーター用のLED2個です。

VRとスイッチはちょうどICピッチの基板用の物が入手できましたので、ブレッドボード上で組めます。が、足の太さや長さの関係で抜けやすかったりするのが難点。

部品表(BOM)

IC1              4051 Analog Mux
LED1             Red LED - 5mm
LED2             Red LED - 5mm
MIDI OUT DIN5P   DIN-5 jack (MIDI)
R1               10kΩ Resistor
R2               1kΩ Resistor
R3               1kΩ Resistor
R4               220Ω Resistor
S1               Pushbutton
VR1              Big Potentiometer 100kΩ
VR2              Big Potentiometer 100kΩ
VR3              Big Potentiometer 100kΩ
VR4              Big Potentiometer 100kΩ
VR5              Big Potentiometer 100kΩ
VR6              Big Potentiometer 100kΩ
VR7              Big Potentiometer 100kΩ
VR8              Big Potentiometer 100kΩ
VR9 TEMPO        Big Potentiometer 100kΩ

スケッチ

次はスケッチ（プログラム）です。

やることはそれほど難しくありません。マルチプレクサのコントロールインプット(A/B/C)に0~7までを順番に2進数で送ってやります。
例えばA=0,B=0,C=0を送るとVR1がスイッチで繋がりますのでその時のアナログ値を読んで、MIDIノートにして送る。次にA=1,B=0,C=0……っていうように繰り返します。

MIDIノートナンバー（音の高さ）は0~127となっています。
Arduinoのアナログインから読み取った値は1024段階ですので、単純に8で割れば0~127になるのですが、実際これでやると音の範囲が広すぎて使いにくいです（ピアノでも88鍵ですからね）。ですので、今回はノートナンバー36から始まる1オクターブ分に限定しています。

スイッチを切り替える間隔ですが、本当はArduino内蔵のタイマーを使って正確なテンポを作ってやるといいのですが、今回はとりあえず動かしてみよう！ってことでかなり簡略化してdelay()を使ってテキトーな間隔で切り替えています。
LEDの点滅にもdelay()を使っているため、そこでも遅れが発生します。のでワンループごとにちょっとずつ遅れます。

今回は Arduino MIDI Library(v2.5)を使っていますので、ライブラリをダウンロードして、予めArduinoのIDEから使えるように入れておきます。
Macの場合はArduino.appを右クリックしてパッケージの中身を表示させ、Contents/Resources/Java/hardware/libraries の中に突っ込んでおけば動きます。（他にやり方あるのかな？）

MIDI SEQUENCER スケッチ

#include <MIDI.h>


// 4051 multiplexer to analog in
// http://www.arduino.cc/playground/Learning/4051

// MIDI Library 
// http://www.arduino.cc/playground/Main/MIDILibrary


int ledPin = 13;
int led2Pin = 12;
int sensorPin = 0;
int tempoPin = 1;
int startBtnPin = 5;

int sensorValue = 0;
int midiValue = 0;
int tempoValue = 0;
int startBtn = 0;
int old_val = 0;
int running = 0;

int r0 = 0;    // 4051 A
int r1 = 0;    // 4051 B
int r2 = 0;    // 4051 C
int row = 0;    // storeing the bin code
int count = 0;
byte bin[] = {0,1,10,11,100,101,110,111};    //bin array org
//byte bin[] = {101,111,110,100,10,1,0,11};  //for mk225 order


void blink(int pin){
   digitalWrite(pin, HIGH);
   delay(20);
   digitalWrite(pin, LOW);
}

void sequence(){
    if(count > 7){
      count = 0;
      blink(ledPin);
    }
    
    row = bin[count];
    r0 = row & 0x01;
    r1 = (row>>1) & 0x01;
    r2 = (row>>2) & 0x01;
    
    digitalWrite(2,r0);
    digitalWrite(3,r1);
    digitalWrite(4,r2);
    
    sensorValue = analogRead(sensorPin);
    midiValue = sensorValue/85.33+36;
    MIDI.sendNoteOn(midiValue,127,1);
    
    tempoValue = analogRead(tempoPin);

    blink(led2Pin);
    delay(tempoValue+10);
    MIDI.sendNoteOff(midiValue,0,1);
    count++;
  }
  
 void stop_sequence(){
   MIDI.sendControlChange(123,0,1);  //all note off cc
   count = 0;
 }
  

void setup(){
  
  pinMode(2, OUTPUT);    //A
  pinMode(3, OUTPUT);     //B
  pinMode(4, OUTPUT);     //C
  pinMode(startBtnPin,INPUT);
  pinMode(ledPin,OUTPUT);
  pinMode(led2Pin,OUTPUT);
  
  digitalWrite(ledPin, LOW);
  digitalWrite(led2Pin, LOW);
  MIDI.begin(1);

}

void loop(){
  startBtn = digitalRead(startBtnPin);
  if((startBtn == HIGH) && (old_val == LOW)){
    running = 1-running;
    delay(10);
    if(running == 0){
      stop_sequence();
    }
  }
  old_val = startBtn;

  
  if(running == 1){
    sequence();
  }

}

midi_sequencer.zip

肝心の使ってるところの動画などはまた次にでも。